; Форум (2 варiант)
$DEBUG=1
$Layer=ID11293
$Parameter=ID7024
@ExecuteMenu ViewShowAll
; точковi шари [3]ID [4]назва
@Text[1].Clear
@Text[2].Clear
; лiнiйнi шари [3]ID [4]назва
@Text[3].Clear
@Text[4].Clear
$LCount=@Map.Layers.Count
@While $LCount>0 %LoopLayer
$LParam=@Map.Layers.Get $LCount
$LType=@StringPart 2 $LParam
$LName=@Map.Layers.GetName $LCount
$LECount=@Map.Layers.ObjectCount $LCount
@If (($LType=3) Or ($LType=4)) And ($LECount>0) Then @Text[1].Add $LCount
@If (($LType=3) Or ($LType=4)) And ($LECount>0) Then @Text[2].Add $LName
;
@If ($LType=1) And ($LECount>0) Then @Text[3].Add $LCount
@If ($LType=1) And ($LECount>0) Then @Text[4].Add $LName
$LCount=$LCount-1
%LoopLayer
;
$Buf=@Text[2].Text
$SPoint=@Dialog.ListSelect Виберiть шар КТП|$Buf
@If $SPoint= Then @Break
$I=@Text[2].IndexOf $SPoint
$SID=@Text[1].Line[$I]
;
$Buf=@Text[4].Text
$SLine=@Dialog.ListSelect Виберiть шар напрямкiв лiнiй|$Buf
@If $SLine= Then @Break
$I=@Text[4].IndexOf $SLine
$RID=@Text[3].Line[$I]
;
@Map.DeselectAll
@Map.SelectLayer $SID
$Buf=@Map.Selected.List
@Text[1].Text=$Buf
@Map.Layers.SetState $SID 3
;
@Map.DeselectAll
@Map.SelectLayer $RID
@ExecuteMenu spbJoin
@Map.SelectLayer $RID
@ExecuteMenu spbSplit
@Map.SelectLayer $RID
@ExecuteMenu spbFragments
@Map.SelectLayer $RID
$Buf=@Map.Selected.List
@Text[3].Text=$Buf
@Map.Layers.SetState $SID 0
@Map.DeselectAll
;
; цикл по точках
$Index=1
@Text[10].Clear
@Text[11].Clear
$pCount=@Text[1].Count
@While $pCount>0 %LoopPoints
$PointObj=@Text[1].Line[$pCount]
$X=@Map.Object[$PointObj].Point[1].x
$Y=@Map.Object[$PointObj].Point[1].y
@Text[11].Add $X $Y
; цикл по лiнiях
%MainCycle
@Text[5].Clear
$lCount=@Text[3].Count
@While $lCount>0 %LoopLines
$LineObj=@Text[3].Line[$lCount]
$A=@Text[10].IndexOf $LineObj
@If $A>0 Then @Goto %SkipLines
;
$X1=@Map.Object[$LineObj].Point[1].x
$Y1=@Map.Object[$LineObj].Point[1].y
;
$PtCount=@Map.Object[$LineObj].Count
$X2=@Map.Object[$LineObj].Point[$PtCount].x
$Y2=@Map.Object[$LineObj].Point[$PtCount].y
;
@If (("$X1"<>"$X") Or ("$Y1"<>"$Y")) And (("$X2"<>"$X") Or ("$Y2"<>"$Y")) Then @Goto %SkipLines
@If "$X1"="$X" Then @Goto %NextStep
@Map.Object[$LineObj].Reverse
%NextStep
$Perim=@Map.Object[$LineObj].Parameter[-1]
$Perim=%Library.ReplaceComma $Perim
$Perim=$Perim/10000
$Perim=@RoundTo $Perim 6
@Text[5].Add $Perim $LineObj
;
%SkipLines
$lCount=$lCount-1
%LoopLines
; сортуємо i додаємо в загальний масив
@Text[5].Sort
$Count=@Text[5].Count
$I=1
@While $I<=$Count %LoopArray
$Line=@Text[5].Line[$I]
$Obj=@StringPart 2 $Line
@Text[10].Add $Obj
$I=$I+1
%LoopArray
;
$pCount=$pCount-1
%LoopPoints
;
$Buf=@Text[10].Text
$Count=@Text[10].Count
@If $Index>$Count Then @Goto %MarkPoints
$Obj=@Text[10].Line[$Index]
$PtCount=@Map.Object[$Obj].Count
$X=@Map.Object[$Obj].Point[$PtCount].x
$Y=@Map.Object[$Obj].Point[$PtCount].y
$Index=$Index+1
@Goto %MainCycle
;
%MarkPoints
$PointNumber=1
$Count=@Text[10].Count
$I=1
@While $I<=$Count %LoopMark
$Obj=@Text[10].Line[$I]
$PtCount=@Map.Object[$Obj].Count
$J=1
@While $J<=$PtCount %LoopMarkPoints
$X=@Map.Object[$Obj].Point[$J].x
$Y=@Map.Object[$Obj].Point[$J].y
$Index=@Text[11].IndexOf $X $Y
@If $Index>0 Then @Goto %SkipMarkPoints
@Text[11].Add $X $Y
$PointObj=@Map.AddObject 0|1|$Layer|1|0 $X $Y 0|1|$Layer|2|$Parameter $PointNumber|114 Проміжна з/б опора~7026:1
@Map.Object[$PointObj].CreateCaption $Parameter 0 0 1 0 3 0
@Map.RefreshObject $PointObj
$PointNumber=$PointNumber+1
%SkipMarkPoints
$J=$J+1
%LoopMarkPoints
$I=$I+1
%LoopMark